home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Grab Bag
/
Shareware Grab Bag.iso
/
001
/
telxauto.arc
/
AUTO.SCR
< prev
Wrap
Text File
|
1987-03-03
|
7KB
|
195 lines
;
; PROGRAM: AUTO.SCR
;
; Telix v2.12 Timed Execution Script.
;
; PURPOSE: To automate PCBoard v11.7 operations.
;
; USAGE: TELIX.EXE /SAUTO.SCR
;
; FUNCTIONS: AutoDial and Connect to Local TeleNet.
; AutoLink to PCPursuit Target Areacode.
; AutoDial and AutoLogOn to Remote PCBB.
; UpLoad File to PCBB 11.7 using Ymodem.
; Enter a pre-recorded Message to Users.
; DownLoad a File using Ymodem Protocol.
; Enter a pre-recorded Message to SysOp.
; LogOff PCBB Host and Disconnect Modem.
;
; NOTES: Remove ALL ;Comments before Execution.
;
; AutoLogOn performance can be improved
; by tuning the code for a specific BBS.
;
;
; CONFIGURATION:
;
; Enter your Local PCPursuit TeleNet Phone Number;
; enter the Area Code of the Target City and your
; PCPursuit UserID and PassWord. ( Delete all this
; if you wish to make a Direct-Dial Connection ).
;
; Enter the Remote PCBB System Phone Number; your
; FirstName, LastName, and PassWord.
;
; Specify the File Name and Description to Upload;
; Record the Message to be sent to all PCBB Users.
;
; Specify the File Name to DownLoad and Record the
; Message to be sent to the PCBB Sysop.
;
; Make sure the \PATH name of the AUTO.LOG Capture
; File is consistent with your Directory structure.
;
; Specify a starting time from 00:00 - 24:00 Hours.
;
;
;
WAITTILL "18:08:10" ; Specify Time of Execution
ONLOG "D:\AUTO.LOG" ; Specify d:\path Capture Filespec
REDO:
HANGUP
DELAY 80
FLUSHBUF
;
TIMEOUT 48 REDO
SEND "ATDT9565777|" ; Specify Local TeleNet Phone Number
WAITFOR "1200"
TIMEOUT 8 DONE
SEND "~~|"
SEND "D|"
WAITFOR "="
SEND "~D1|"
WAITFOR "@"
AREA:
TIMEOUT 8 RSTZ ; Specify Target City AreaCode
SEND "C DIAL415/12,USERID,PASSWORD|" ; Specify PCP UserID and PassWord
WAITFOR "@"
GOTO AREA
RSTZ:
TIMEOUT 8 DONE
SEND "ATZ|"
WAITFOR "OK"
SEND "~ATX1S11=55|" ;( Configures Out-Dial Modem )
WAITFOR "OK"
SEND "~|@|"
WAITFOR "@"
SEND "SET? 1:0,4:2,7:8|" ;( Configures TeleNet for File Xfers )
WAITFOR "@"
SEND "CONT|~"
DELAY 20
FLUSHBUF
;
TIMEOUT 48 OUTD
OUTD:
SEND "ATDT9649039|" ; Specify Phone Number of PCBoard
WAITFOR "1200"
;
TIMEOUT 16 USER
WAITFOR "=no?"
SEND "Y;Q|"
WAITFOR "?"
USER:
SEND "FIRSTNAME;LASTNAME;PASSWORD|" ; Specify PCBoard User information
TIMEOUT 24 NEXT
WAITFOR "?"
NEXT:
TIMEOUT 16 NEXT
SEND "|"
WAITFOR "Command?"
;
TIMEOUT 32 POST ;( Note this is a PCBB 11.7 procedure )
SEND "~|"
WAITFOR "Command?"
SEND "U TELXAUTO.ARC Y|" ; Specify File Name and Description
WAITFOR "---]"
SEND "Telix v2.12 Automatic PCBB Script |"
WAITFOR "Abort."
UPLOAD YM "C:\LIB\TELXAUTO.ARC" ; Enter d:\path\filename to UpLoad
;
POST:
TIMEOUT 16 DOWN
SEND "~|"
WAITFOR "Command?"
SEND 'E|'
WAITFOR '?'
SEND '|'
WAITFOR '?'
SEND 'Telix PCBB Script |' ; Enter Subject and Message to Post
WAITFOR '?'
SEND '|'
WAITFOR '1:'
SEND "╔═════════════════════════════════════════════════════════════╗|~"
SEND "║ ║|~"
SEND "║ File TELXAUTO.ARC is a timed-execution Script to: ║|~"
SEND "║ ║|~"
SEND "║ (1) AutoDial and Connect to Local TeleNet. ║|~"
SEND "║ (2) AutoLink to PCPursuit Target Areacode. ║|~"
SEND "║ (3) AutoDial and AutoLogOn to Remote PCBB. ║|~"
SEND "║ (4) UpLoad File to PCBB 11.7 using Ymodem. ║|~"
SEND "║ (5) Enter a pre-recorded Message to Users. ║|~"
SEND "║ (6) DownLoad a File using Ymodem Protocol. ║|~"
SEND "║ (7) Enter a pre-recorded Message to SysOp. ║|~"
SEND "║ (8) LogOff PCBB Host and Disconnect Modem. ║|~"
SEND "║ ║|~"
SEND "║ It is capable of unattended operation of this PCBB. ║|~"
SEND "║ ║|~"
SEND "╚═════════════════════════════════════════════════════════════╝|"
TIMEOUT 80 DOWN
WAITFOR '17:'
SEND '|'
TIMEOUT 16 DOWN
WAITFOR '?'
SEND 'S|'
;
DOWN:
TIMEOUT 32 CHAT
SEND "~|"
WAITFOR "Command?"
SEND "D ALLFILES.ARC Y|" ; Specify File Name to DownLoad
WAITFOR "Abort."
DOWNLOAD YM "C:\WRK\ALLFILES.ARC" ; Enter d:\path\filename to DownLoad
;
CHAT:
TIMEOUT 16 OVER ; Enter text of Message to SysOp
SEND "~|"
WAITFOR "Command?"
SEND "C|"
WAITFOR "?"
SEND "Y|"
WAITFOR "1:"
SEND "╔═════════════════════════════════════════════════════════════╗|~"
SEND "║ ║|~"
SEND "║ ║|~"
SEND "║ Thanks for the File! ║|~"
SEND "║ ║|~"
SEND "║ Your PCBB has been operated by a Telix Script File! ║|~"
SEND "║ ║|~"
SEND "║ The Script was UpLoaded to you as File TELXAUTO.ARC ║|~"
SEND "║ ║|~"
SEND "║ Please feel free to customize this Script for your ║|~"
SEND "║ PCBoard and distribute it to your users. ║|~"
SEND "║ ║|~"
SEND "║ Auto T. Script ║|~"
SEND "║ ║|~"
SEND "║ ║|~"
SEND "╚═════════════════════════════════════════════════════════════╝|"
TIMEOUT 80 OVER
WAITFOR "17:"
SEND "|"
TIMEOUT 16 OVER
WAITFOR "?"
SEND "S|"
;
OVER:
TIMEOUT 8 DONE
SEND "~|"
WAITFOR "Command?"
SEND "G|"
WAITFOR "..."
;
DONE:
HANGUP
OFFLOG
STOP ; Remove ALL ;Comments before Execution.